msan_arm64.s

Documentation: runtime

     1  // Copyright 2018 The Go Authors. All rights reserved.
     2  // Use of this source code is governed by a BSD-style
     3  // license that can be found in the LICENSE file.
     4  
     5  //go:build msan
     6  // +build msan
     7  
     8  #include "go_asm.h"
     9  #include "textflag.h"
    10  
    11  #define RARG0 R0
    12  #define RARG1 R1
    13  #define RARG2 R2
    14  #define FARG R3
    15  
    16  // func runtime·domsanread(addr unsafe.Pointer, sz uintptr)
    17  // Called from msanread.
    18  TEXT	runtime·domsanread(SB), NOSPLIT, $0-16
    19  	MOVD	addr+0(FP), RARG0
    20  	MOVD	size+8(FP), RARG1
    21  	// void __msan_read_go(void *addr, uintptr_t sz);
    22  	MOVD	$__msan_read_go(SB), FARG
    23  	JMP	msancall<>(SB)
    24  
    25  // func runtime·msanwrite(addr unsafe.Pointer, sz uintptr)
    26  // Called from instrumented code.
    27  TEXT	runtime·msanwrite(SB), NOSPLIT, $0-16
    28  	MOVD	addr+0(FP), RARG0
    29  	MOVD	size+8(FP), RARG1
    30  	// void __msan_write_go(void *addr, uintptr_t sz);
    31  	MOVD	$__msan_write_go(SB), FARG
    32  	JMP	msancall<>(SB)
    33  
    34  // func runtime·msanmalloc(addr unsafe.Pointer, sz uintptr)
    35  TEXT	runtime·msanmalloc(SB), NOSPLIT, $0-16
    36  	MOVD	addr+0(FP), RARG0
    37  	MOVD	size+8(FP), RARG1
    38  	// void __msan_malloc_go(void *addr, uintptr_t sz);
    39  	MOVD	$__msan_malloc_go(SB), FARG
    40  	JMP	msancall<>(SB)
    41  
    42  // func runtime·msanfree(addr unsafe.Pointer, sz uintptr)
    43  TEXT	runtime·msanfree(SB), NOSPLIT, $0-16
    44  	MOVD	addr+0(FP), RARG0
    45  	MOVD	size+8(FP), RARG1
    46  	// void __msan_free_go(void *addr, uintptr_t sz);
    47  	MOVD	$__msan_free_go(SB), FARG
    48  	JMP	msancall<>(SB)
    49  
    50  // func runtime·msanmove(dst, src unsafe.Pointer, sz uintptr)
    51  TEXT	runtime·msanmove(SB), NOSPLIT, $0-24
    52  	MOVD	dst+0(FP), RARG0
    53  	MOVD	src+8(FP), RARG1
    54  	MOVD	size+16(FP), RARG2
    55  	// void __msan_memmove(void *dst, void *src, uintptr_t sz);
    56  	MOVD	$__msan_memmove(SB), FARG
    57  	JMP	msancall<>(SB)
    58  
    59  // Switches SP to g0 stack and calls (FARG). Arguments already set.
    60  TEXT	msancall<>(SB), NOSPLIT, $0-0
    61  	MOVD	RSP, R19                  // callee-saved
    62  	CBZ	g, g0stack                // no g, still on a system stack
    63  	MOVD	g_m(g), R10
    64  	MOVD	m_g0(R10), R11
    65  	CMP	R11, g
    66  	BEQ	g0stack
    67  
    68  	MOVD	(g_sched+gobuf_sp)(R11), R4
    69  	MOVD	R4, RSP
    70  
    71  g0stack:
    72  	BL	(FARG)
    73  	MOVD	R19, RSP
    74  	RET
    75
View as plain text